Not-Enough-Crashes/neoforge/build.gradle

plugins {
    alias libs.plugins.shadow
}

architectury {
    platformSetupLoomIde()
    neoForge()
}

configurations {
    common {
        canBeResolved = true
        canBeConsumed = false
    }
    compileClasspath.extendsFrom common
    runtimeClasspath.extendsFrom common
    developmentNeoForge.extendsFrom common

    // Files in this configuration will be bundled into your mod using the Shadow plugin.
    // Don't use the `shadow` configuration from the plugin itself as it's meant for excluding files.
    shadowBundle {
        canBeResolved = true
        canBeConsumed = false
    }
}



repositories {
    maven {
        name = 'NeoForged'
        url = 'https://maven.neoforged.net/releases'
    }
}

dependencies {
    neoForge libs.neoforge

    common(project(':common')) { transitive false }
    shadowBundle project(path: ':common', configuration: 'runtimeElements')
}

processResources {
    inputs.property 'version', project.version

    filesMatching('META-INF/neoforge.mods.toml') {
        expand version: project.version
    }
}

shadowJar {
    configurations = [project.configurations.shadowBundle]
    archiveClassifier = 'dev-shadow'
}

jar {
    from(project(':common').sourceSets.main.output)
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
}

def forge_release  = "release"

plugins.withId("com.matthewprenger.cursegradle") {
    curseforge {
        apiKey = project.hasProperty("curseforge_api_key") ? project.curseforge_api_key : ""
        project {
            id = "442354"
            releaseType = forge_release
            addGameVersion "NeoForge"
            addGameVersion curseforge_mc_version
            changelogType = "markdown"
            changelog = rootProject.file("changelog.md")

            mainArtifact(jar) {
                displayName = "$mod_name $total_version NeoForge"
            }
        }

        options {
            forgeGradleIntegration = false
        }
    }
}

plugins.withId("com.modrinth.minotaur") {
    modrinth {
        group = "upload"
        token =  project.hasProperty("modrinth_api_key") ? project.modrinth_api_key : ""
        projectId = 'yM94ont6'
        versionNumber = total_version + "-neoforge" // Will fail if Modrinth has this version already
        versionName = "$mod_name $total_version NeoForge"
        uploadFile = jar
        gameVersions = [modrinth_mc_version]
        loaders = ["neoforge"]
        changelog = rootProject.file("changelog.md").text
        versionType = forge_release
    }
}


tasks.register('publishForge') {
    group = "publishing"
    dependsOn("curseforge442354", "modrinth")
}