Not-Enough-Crashes/neoforge/build.gradle

plugins {
    alias libs.plugins.shadow
}

architectury {
    platformSetupLoomIde()
    neoForge()
}

configurations {
    common {
        canBeResolved = true
        canBeConsumed = false
    }
    compileClasspath.extendsFrom common
    runtimeClasspath.extendsFrom common
    developmentNeoForge.extendsFrom common

    // Files in this configuration will be bundled into your mod using the Shadow plugin.
    // Don't use the `shadow` configuration from the plugin itself as it's meant for excluding files.
    shadowBundle {
        canBeResolved = true
        canBeConsumed = false
    }
}



repositories {
    maven {
        name = 'NeoForged'
        url = 'https://maven.neoforged.net/releases'
    }
}

dependencies {
    neoForge libs.neoforge

    common(project(path: ':common', configuration: 'namedElements')) { transitive false }
    shadowBundle project(path: ':common', configuration: 'transformProductionNeoForge')
}

processResources {
    inputs.property 'version', project.version

    filesMatching('META-INF/neoforge.mods.toml') {
        expand version: project.version
    }
}

shadowJar {
    configurations = [project.configurations.shadowBundle]
    archiveClassifier = 'dev-shadow'
}

remapJar {
    inputFile.set shadowJar.archiveFile
}

def forge_release  = "release"

curseforge {
    apiKey = project.hasProperty("curseforge_api_key") ? project.curseforge_api_key : ""
    project {
        id = "442354"
        releaseType = forge_release
        addGameVersion "NeoForge"
        addGameVersion curseforge_mc_version
        changelogType = "markdown"
        changelog = rootProject.file("changelog.md")

        mainArtifact(remapJar) {
            displayName = "$mod_name $total_version NeoForge"
        }
    }

    options {
        forgeGradleIntegration = false
    }
}

modrinth {
    group = "upload"
    token =  project.hasProperty("modrinth_api_key") ? project.modrinth_api_key : ""
    projectId = 'yM94ont6'
    versionNumber = total_version + "-neoforge" // Will fail if Modrinth has this version already
    versionName = "$mod_name $total_version NeoForge"
    uploadFile = remapJar
    gameVersions = [modrinth_mc_version]
    loaders = ["neoforge"]
    changelog = rootProject.file("changelog.md").text
    versionType = forge_release
}


task publishForge {
    group = "publishing"
    afterEvaluate {
        dependsOn(curseforge442354)
        dependsOn(tasks.modrinth)
    }
}